[libvirt] [PATCH 46/89] configure: move loader/nvram check to its own file

[Pavel Hrdina]

Signed-off-by: Pavel Hrdina <phrdina at redhat.com>
---
 configure.ac            | 17 +++--------------
 m4/virt-loader-nvram.m4 | 41 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 44 insertions(+), 14 deletions(-)
 create mode 100644 m4/virt-loader-nvram.m4

diff --git a/configure.ac b/configure.ac
index 89f3ab9bf8..d6df45e0a9 100644
--- a/configure.ac
+++ b/configure.ac
@@ -1683,19 +1683,8 @@ AC_DEFINE_UNQUOTED([STATIC_ANALYSIS], [$t],
 LIBVIRT_ARG_WITH_ALT([DEFAULT_EDITOR], [Editor to use for interactive commands], [vi])
 AC_DEFINE_UNQUOTED([DEFAULT_EDITOR], ["$with_default_editor"], [Default editor to use])
 
-LIBVIRT_ARG_WITH_ALT([LOADER_NVRAM],
-                     [Pass list of pairs of <loader>:<nvram> paths.
-                      Both pairs and list items are separated by a colon.],
-                     [''])
-if test "x$with_loader_nvram" != "xno" && \
-   test "x$with_loader_nvram" != "x" ; then
-    l=$(echo $with_loader_nvram | tr ':' '\n' | wc -l)
-    if test $(expr $l % 2) -ne 0 ; then
-        AC_MSG_ERROR([Malformed --with-loader-nvram argument])
-    fi
-    AC_DEFINE_UNQUOTED([DEFAULT_LOADER_NVRAM], [$with_loader_nvram],
-                       [List of loader:nvram pairs])
-fi
+LIBVIRT_ARG_LOADER_NVRAM
+LIBVIRT_CHECK_LOADER_NVRAM
 
 # Some GNULIB base64 symbols clash with a kerberos library
 AC_DEFINE_UNQUOTED([isbase64],[libvirt_gl_isbase64],[Hack to avoid symbol clash])
@@ -1854,7 +1843,7 @@ AC_MSG_NOTICE([       XML Catalog: $with_xml_catalog_file])
 LIBVIRT_RESULT_INIT_SCRIPT
 LIBVIRT_RESULT_CHRDEV_LOCK_FILES
 AC_MSG_NOTICE([    Default Editor: $with_default_editor])
-AC_MSG_NOTICE([      Loader/NVRAM: $with_loader_nvram])
+LIBVIRT_RESULT_LOADER_NVRAM
 LIBVIRT_RESULT_LOGIN_SHELL
 LIBVIRT_RESULT_HOST_VALIDATE
 AC_MSG_NOTICE([      TLS priority: $with_tls_priority])
diff --git a/m4/virt-loader-nvram.m4 b/m4/virt-loader-nvram.m4
new file mode 100644
index 0000000000..e57ba829f4
--- /dev/null
+++ b/m4/virt-loader-nvram.m4
@@ -0,0 +1,41 @@
+dnl The loader:nvram list check
+dnl
+dnl Copyright (C) 2016 Red Hat, Inc.
+dnl
+dnl This library is free software; you can redistribute it and/or
+dnl modify it under the terms of the GNU Lesser General Public
+dnl License as published by the Free Software Foundation; either
+dnl version 2.1 of the License, or (at your option) any later version.
+dnl
+dnl This library is distributed in the hope that it will be useful,
+dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+dnl Lesser General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU Lesser General Public
+dnl License along with this library.  If not, see
+dnl <http://www.gnu.org/licenses/>.
+dnl
+
+AC_DEFUN([LIBVIRT_ARG_LOADER_NVRAM], [
+  LIBVIRT_ARG_WITH_ALT([LOADER_NVRAM],
+                       [Pass list of pairs of <loader>:<nvram> paths.
+                        Both pairs and list items are separated by a colon.],
+                       [''])
+])
+
+AC_DEFUN([LIBVIRT_CHECK_LOADER_NVRAM], [
+  if test "x$with_loader_nvram" != "xno" && \
+     test "x$with_loader_nvram" != "x" ; then
+    l=$(echo $with_loader_nvram | tr ':' '\n' | wc -l)
+    if test $(expr $l % 2) -ne 0 ; then
+      AC_MSG_ERROR([Malformed --with-loader-nvram argument])
+    fi
+    AC_DEFINE_UNQUOTED([DEFAULT_LOADER_NVRAM], [$with_loader_nvram],
+                       [List of loader:nvram pairs])
+  fi
+])
+
+AC_DEFUN([LIBVIRT_RESULT_LOADER_NVRAM], [
+  AC_MSG_NOTICE([      Loader/NVRAM: $with_loader_nvram])
+])
-- 
2.11.0