[libvirt] [PATCH 69/89] configure: move ESX driver check to its own file

[Pavel Hrdina]

Signed-off-by: Pavel Hrdina <phrdina at redhat.com>
---
 configure.ac          | 31 +++-------------------------
 m4/virt-driver-esx.m4 | 57 +++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+), 28 deletions(-)
 create mode 100644 m4/virt-driver-esx.m4

diff --git a/configure.ac b/configure.ac
index 1356568a09..879235cd1e 100644
--- a/configure.ac
+++ b/configure.ac
@@ -407,7 +407,7 @@ LIBVIRT_DRIVER_ARG_XENAPI
 LIBVIRT_DRIVER_ARG_LIBXL
 LIBVIRT_DRIVER_ARG_VBOX
 LIBVIRT_DRIVER_ARG_LXC
-LIBVIRT_ARG_WITH([ESX], [ESX], [check])
+LIBVIRT_DRIVER_ARG_ESX
 LIBVIRT_ARG_WITH([HYPERV], [Hyper-V], [check])
 LIBVIRT_DRIVER_ARG_TEST
 LIBVIRT_DRIVER_ARG_REMOTE
@@ -973,32 +973,7 @@ dnl
 dnl check for (ESX)
 dnl
 
-if test "$with_curl" != "yes" ; then
-  if test "$with_esx" != "yes"; then
-    with_esx=no
-  else
-    AC_MSG_ERROR([Curl is required for the ESX driver])
-  fi
-else
-  if test "$with_esx" = "check"; then
-    with_esx=yes
-  fi
-fi
-
-if test "$with_esx" = "yes" ; then
-    AC_DEFINE_UNQUOTED([WITH_ESX], 1, [whether ESX driver is enabled])
-fi
-AM_CONDITIONAL([WITH_ESX], [test "$with_esx" = "yes"])
-
-with_vmx=yes
-if test "$with_esx" != "yes" && test "$with_vmware" != "yes"; then
-  with_vmx=no
-fi
-if test "$with_vmx" = "yes" ; then
-  AC_DEFINE_UNQUOTED([WITH_VMX], 1, [whether VMware VMX config handling is enabled])
-fi
-AM_CONDITIONAL([WITH_VMX], [test "$with_vmx" = "yes"])
-
+LIBVIRT_DRIVER_CHECK_ESX
 
 dnl
 dnl check for Hyper-V
@@ -1343,7 +1318,7 @@ LIBVIRT_DRIVER_RESULT_XENAPI
 LIBVIRT_DRIVER_RESULT_LIBXL
 LIBVIRT_DRIVER_RESULT_LXC
 LIBVIRT_DRIVER_RESULT_PHYP
-AC_MSG_NOTICE([      ESX: $with_esx])
+LIBVIRT_DRIVER_RESULT_ESX
 AC_MSG_NOTICE([  Hyper-V: $with_hyperv])
 LIBVIRT_DRIVER_RESULT_VZ
 LIBVIRT_DRIVER_RESULT_BHYVE
diff --git a/m4/virt-driver-esx.m4 b/m4/virt-driver-esx.m4
new file mode 100644
index 0000000000..c751d6d350
--- /dev/null
+++ b/m4/virt-driver-esx.m4
@@ -0,0 +1,57 @@
+dnl The ESX driver
+dnl
+dnl Copyright (C) 2016 Red Hat, Inc.
+dnl
+dnl This library is free software; you can redistribute it and/or
+dnl modify it under the terms of the GNU Lesser General Public
+dnl License as published by the Free Software Foundation; either
+dnl version 2.1 of the License, or (at your option) any later version.
+dnl
+dnl This library is distributed in the hope that it will be useful,
+dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+dnl Lesser General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU Lesser General Public
+dnl License along with this library.  If not, see
+dnl <http://www.gnu.org/licenses/>.
+dnl
+
+AC_DEFUN([LIBVIRT_DRIVER_ARG_ESX], [
+  LIBVIRT_ARG_WITH([ESX], [ESX], [check])
+])
+
+AC_DEFUN([LIBVIRT_DRIVER_CHECK_ESX], [
+  AC_REQUIRE([LIBVIRT_CHECK_CURL])
+  AC_REQUIRE([LIBVIRT_DRIVER_CHECK_VMWARE])
+
+  if test "$with_curl" != "yes" ; then
+    if test "$with_esx" != "yes"; then
+      with_esx=no
+    else
+      AC_MSG_ERROR([Curl is required for the ESX driver])
+    fi
+  else
+    if test "$with_esx" = "check"; then
+      with_esx=yes
+    fi
+  fi
+
+  if test "$with_esx" = "yes" ; then
+    AC_DEFINE_UNQUOTED([WITH_ESX], 1, [whether ESX driver is enabled])
+  fi
+  AM_CONDITIONAL([WITH_ESX], [test "$with_esx" = "yes"])
+
+  with_vmx=yes
+  if test "$with_esx" != "yes" && test "$with_vmware" != "yes"; then
+    with_vmx=no
+  fi
+  if test "$with_vmx" = "yes" ; then
+    AC_DEFINE_UNQUOTED([WITH_VMX], 1, [whether VMware VMX config handling is enabled])
+  fi
+  AM_CONDITIONAL([WITH_VMX], [test "$with_vmx" = "yes"])
+])
+
+AC_DEFUN([LIBVIRT_DRIVER_RESULT_ESX], [
+  LIBVIRT_RESULT([ESX], [$with_esx])
+])
-- 
2.11.0