[libvirt] [PATCH 1/2] configure: split out UML driver checks
Roman Bogorodskiy
bogorodskiy at gmail.com
Thu May 5 07:33:38 UTC 2016
Roman Bogorodskiy wrote:
> Move all the UML driver related routines into m4/virt-driver-uml.m4.
> ---
> configure.ac | 28 ++--------------------------
> m4/virt-driver-uml.m4 | 47 +++++++++++++++++++++++++++++++++++++++++++++++
> 2 files changed, 49 insertions(+), 26 deletions(-)
> create mode 100644 m4/virt-driver-uml.m4
>
> diff --git a/configure.ac b/configure.ac
> index 88e2e20..d19c1a9 100644
> --- a/configure.ac
> +++ b/configure.ac
> @@ -537,10 +537,6 @@ AC_ARG_WITH([qemu],
> [AS_HELP_STRING([--with-qemu],
> [add QEMU/KVM support @<:@default=yes@:>@])])
> m4_divert_text([DEFAULTS], [with_qemu=yes])
> -AC_ARG_WITH([uml],
> - [AS_HELP_STRING([--with-uml],
> - [add UML support @<:@default=check@:>@])])
> -m4_divert_text([DEFAULTS], [with_uml=check])
> AC_ARG_WITH([openvz],
> [AS_HELP_STRING([--with-openvz],
> [add OpenVZ support @<:@default=check@:>@])])
> @@ -1561,27 +1557,7 @@ dnl
> dnl Checks for the UML driver
> dnl
>
> -if test "$with_libvirtd" = "no" ; then
> - with_uml=no
> -fi
^^^
Bah, I forgot to move this chunk. I'll wait for other comments before
sending out v2 though.
> -if test "$with_uml" = "yes" || test "$with_uml" = "check"; then
> - AC_CHECK_HEADER([sys/inotify.h], [
> - with_uml=yes
> - ], [
> - if test "$with_uml" = "check"; then
> - with_uml=no
> - AC_MSG_NOTICE([<sys/inotify.h> is required for the UML driver, disabling it])
> - else
> - AC_MSG_ERROR([The <sys/inotify.h> is required for the UML driver. Upgrade your libc6.])
> - fi
> - ])
> -fi
> -if test "$with_uml" = "yes" ; then
> - AC_DEFINE_UNQUOTED([WITH_UML], 1, [whether UML driver is enabled])
> -fi
> -AM_CONDITIONAL([WITH_UML], [test "$with_uml" = "yes"])
> -
> -
> +LIBVIRT_DRIVER_CHECK_UML
>
> dnl
> dnl check for PHYP
> @@ -2747,7 +2723,7 @@ AC_MSG_NOTICE([Drivers])
> AC_MSG_NOTICE([])
> AC_MSG_NOTICE([ Xen: $with_xen])
> AC_MSG_NOTICE([ QEMU: $with_qemu])
> -AC_MSG_NOTICE([ UML: $with_uml])
> +LIBVIRT_DRIVER_RESULT_UML
> AC_MSG_NOTICE([ OpenVZ: $with_openvz])
> AC_MSG_NOTICE([ VMware: $with_vmware])
> AC_MSG_NOTICE([ VBox: $with_vbox])
> diff --git a/m4/virt-driver-uml.m4 b/m4/virt-driver-uml.m4
> new file mode 100644
> index 0000000..4132315
> --- /dev/null
> +++ b/m4/virt-driver-uml.m4
> @@ -0,0 +1,47 @@
> +dnl The UML driver
> +dnl
> +dnl Copyright (C) 2005-2015 Red Hat, Inc.
> +dnl
> +dnl This library is free software; you can redistribute it and/or
> +dnl modify it under the terms of the GNU Lesser General Public
> +dnl License as published by the Free Software Foundation; either
> +dnl version 2.1 of the License, or (at your option) any later version.
> +dnl
> +dnl This library is distributed in the hope that it will be useful,
> +dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
> +dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
> +dnl Lesser General Public License for more details.
> +dnl
> +dnl You should have received a copy of the GNU Lesser General Public
> +dnl License along with this library. If not, see
> +dnl <http://www.gnu.org/licenses/>.
> +dnl
> +
> +AC_DEFUN([LIBVIRT_DRIVER_CHECK_UML],[
> + AC_ARG_WITH([uml],
> + [AS_HELP_STRING([--with-uml],
> + [add UML support @<:@default=check@:>@])])
> + m4_divert_text([DEFAULTS], [with_uml=check])
> +
> + if test "$with_uml" = "yes" || test "$with_uml" = "check"; then
> + AC_CHECK_HEADER([sys/inotify.h], [
> + with_uml=yes
> + ], [
> + if test "$with_uml" = "check"; then
> + with_uml=no
> + AC_MSG_NOTICE([<sys/inotify.h> is required for the UML driver, disabling it])
> + else
> + AC_MSG_ERROR([The <sys/inotify.h> is required for the UML driver. Upgrade your libc6.])
> + fi
> + ])
> + fi
> +
> + if test "$with_uml" = "yes" ; then
> + AC_DEFINE_UNQUOTED([WITH_UML], 1, [whether UML driver is enabled])
> + fi
> + AM_CONDITIONAL([WITH_UML], [test "$with_uml" = "yes"])
> +])
> +
> +AC_DEFUN([LIBVIRT_DRIVER_RESULT_UML],[
> + AC_MSG_NOTICE([ UML: $with_uml])
> +])
> --
> 2.7.4
>
Roman Bogorodskiy
More information about the libvir-list
mailing list